一个不错的趋势多空主图：试盘 – 震仓 – 起爆跟庄体系，看懂主力三段式拉升

很多朋友一直在找一套可以完整还原主力建仓洗盘拉升全过程的主图指标。市面上大多指标只做单一突破，很难区分是真试盘还是诱多，这套趋势多空属于复合型主图，把量价、筹码、趋势均线、资金行为整合到一张K线图，一眼看懂主力试盘、震仓、起爆全流程。

主图信号优先级（从高到低）

指标的核心思路：主力拉升三步骤
主力拉升不会直接连续涨停，标准路径：试盘（测试上方抛压）→震仓（清洗短线浮筹）→起爆（突破启动，进入主升）。主图就是用量价量化，把这三个阶段直接在K线上标出来。

高量区间：锁定主力成本
自动抓取21周期最大成交量K线，画出红色填充高量区间，同步显示高量均价。这是主力集中资金博弈的成本区，高量下沿是强支撑，高量上沿是短期压力。

多空线：趋势分水岭
17周期重心均线作为多空线。K线站稳多空线：多头趋势，只考虑低吸和突破；K线持续在多空线下方：空头，放弃操作。
搭配飞龙强势线，站上飞龙，个股进入强势模式，K实体自动标记黄色。指标自动计算建仓价、加仓区间，方便我们区分潜伏位置和加仓位置。

核心战法：试盘→震仓→起爆
试盘K：长上影放量，试探上方抛压，紫色K线标记。试盘不等于马上涨，只是主力摸底。
震仓K：试盘之后，收阴不创新高，守住多空线上方，标注【震】。这个阶段就是洗浮筹，很多人在这一步被洗下车。
起爆K：洗盘结束，放量突破震仓高点，紫红色K线，是整套指标优先级最高的买入信号。

筹码量化筛选，避开虚突破
内置筹码系数、获利盘 / 套牢盘量化。筹码收敛、套牢盘少、获利盘充足时，出现^标记，代表筹码结构健康。
提示：筹码是通达信模型估算，需要切换【前复权】才能保证数据准确，次新股、僵尸股筹码容易失真。

黄金坑低吸体系
专门抓震盘缩量回调的低吸机会，4 类图标区分不同坑形态：黄金坑、回踩起涨开盘、破位回收、缩量企稳。适合不想追起爆，偏好低吸潜伏的交易者。
额外附加辅助信号：涨停、炸板、T 字板、强庄连板标记、机构启动K、回踩支撑、亿级成交额钱袋子、异动单、抄底信号。

⚠️重要风险提示
本指标仅为技术分析辅助工具，不构成任何投资建议。股市不存在稳赚指标，任何技术信号都存在假突破、诱多的可能性。
WINNER/COST筹码函数为估算模型，不是真实持仓；必须前复权使用。
震荡行情容易反复出信号，需要结合大盘环境、板块热度综合判断。
所有历史回测信号不代表未来收益，交易有风险，入市需谨慎。

趋势多空主图源码：

高量线:=IF(CURRBARSCOUNT<=CONST(REF(HHVBARS(VOL,21),1)+1)+1,CONST(REF(MAX(H,CLOSE),REF(HHVBARS(VOL,21),1)+1)),DRAWNULL),COLORRED,LINETHICK2;
{DRAWTEXT(ISLASTBAR,高量线,' ←高量线'),COLORRED;}
高量线2:=IF(CURRBARSCOUNT<=CONST(REF(HHVBARS(VOL,21),1)+1)+1,CONST(REF(MIN(L,CLOSE),REF(HHVBARS(VOL,21),1)+1)),DRAWNULL),COLORRED,LINETHICK2;
{DRAWTEXT(ISLASTBAR,高量线*1,CON2STR(高量线,2)),COLORWHITE;}
DRAWBAND(高量线,RGB(80,00,20),高量线2,RGB(60,60,18));
高量均:IF(CURRBARSCOUNT<=CONST(REF(HHVBARS(VOL,21),1)+1)+1, CONST(REF(AMOUNT/(VOL*100),REF(HHVBARS(VOL,21),1)+1)), DRAWNULL), COLORWHITE,DOTLINE;
DRAWTEXT(ISLASTBAR,高量均,VARCAT(VARCAT('高量均价：',VAR2STR(高量均,2)),'')),COLORWHITE;
DRAWKLINE(H,O,L,C);
A0:=(L+H+C*2)/4;
多空线:EMA(A0,17),COLOR00FFFF;
趋势线:EMA(多空线,5),COLORFF00FF;
DRAWBAND(多空线,RGB(155,75,245),趋势线,RGB(5,155,15));
DRAWKLINE(H,O,L,C);
A1X:=(多空线-REF(多空线,1))/REF(多空线,1)*100;
拐头:=CROSS(A1X,0);
建仓:REF(A0,BARSLAST(拐头)),COLORRED,NODRAW;
加仓:建仓*1.31,COLORFFAA99,NODRAW;
持续画线:=BARSLAST(拐头)>=0;
{放量突破重心均线信号}
突破:=CROSS(C,多空线);
AMP:=IF(NAMELIKE('ST') OR NAMELIKE('*ST'),0.1,IF(CODELIKE('688') OR CODELIKE('30'),0.2,IF(CODELIKE('8') OR CODELIKE('92'),0.3,0.1)));
ZTP:=ZTPRICE(REF(C,1),AMP);
DTP:=DTPRICE(REF(C,1),AMP);
ZT:=C>=ZTP AND C=H;
DT:=C<=DTP AND C=L;
ZB:=H=ZTP AND C<H;
YZB:=C=O AND H=L;
T字板:=O>=ZTP AND L<C AND C=H;
ZF:=(C-REF(C,1))/REF(C,1)*100,NODRAW;
ZB_HF:=REF(ZB,1) AND ZT AND NOT(YZB);
触跌停:=L=DTP AND C>L;
STICKLINE(触跌停,H,L,0.1,0),COLORFF2200;
STICKLINE(触跌停,L*0.98,L*0.93,0.01,-1),COLOR22FF00;
STICKLINE(YZB,C,O,3,0),COLORAA00AA;
STICKLINE(YZB,C,O,2,0),COLOR888888;
STICKLINE(YZB,C,O,1,0),COLOR80FFFF;
STICKLINE(T字板,C,O,3,0),COLORAA00AA;
STICKLINE(T字板,H,L,0.2,0),COLORAA00AA;
DRAWICON(触跌停,L*0.93,44);
DRAWICON(ZB,H*1.012,23);
DRAWICON(ZB_HF,H*1.015,13);
两连板:=EVERY(ZT,2) AND EXIST(C>O,2);
三连板:=EVERY(ZT,3);
四连板:=EVERY(ZT,4);
三天两板:=COUNT(ZT AND C>O,3)=2
AND C>REF(C,2)
AND NOT(EXIST(两连板,3));
DRAWTEXT(两连板 OR 三天两板 AND NOT(三连板) AND NOT(EXIST(四连板,180)) ,H*1.01,'强庄'),COLOR00AAFF;
上影比:=(H-MAX(C,O))/REF(C,1),NODRAW;
实体比:=ABS(C-O)/REF(C,1),NODRAW;
上影长度:=H-MAX(C,O),NODRAW;
实体长度:=ABS(C-O),NODRAW;
上影振幅:=(H-MAX(C,O))/REF(C,1)*100,NODRAW;
溢价弱化:=REF(C,1)/REF(C,2)<1.097 AND REF(H,1)>REF(C,1);
均价28:=SUM(C*V*100,28)/SUM(V*100,28),NODRAW;
{短线动量差值体系}
均线差值:=EMA(C,5)-EMA(C,10);
差值均线:=EMA(均线差值,9);
短线动量:=差值均线-REF(差值均线,1),NODRAW;
趋势斜率:=均线差值-REF(均线差值,1),NODRAW;
分时均价:=IF(VOL=0,C,AMOUNT/VOL/100),NODRAW;
{筹码量化筛选模块}
峰距:=COST(85)-COST(15);
筹码系数:=峰距/(COST(85)+COST(15))*200,NODRAW;
获利筹码:=WINNER(C)*100,NODRAW;
套牢筹码:=100-获利筹码,NODRAW;
筹码优良:=筹码系数<18 AND 套牢筹码<35 AND 获利筹码>55 AND 筹码系数<REF(筹码系数,1) AND C>MA(C,20) AND NOT(YZB);
盘中护盘:=上影振幅>=3 AND ABS(C-分时均价)/分时均价*100>0 AND 上影长度>=实体长度 AND NOT(YZB) AND NOT(DT) AND C>O;
护盘信号:=FILTER(盘中护盘,2);
STICKLINE(护盘信号,H,L,0.1,0),COLORFFFFFF;
STICKLINE(护盘信号,O,C,1.5,0),COLORCCFFDD;
STICKLINE(护盘信号,O,C,0.8,0),COLOR0000FF;
高量过前5:=C>O AND (V>2*REF(MA(V,5),1) OR V>=2*REF(V,1)) AND C>多空线 AND V>=HHV(V,6);
试盘K:=FILTER((H/REF(C,1)>=1.05 AND H>=HHV(H,6) AND 高量过前5 AND H/C>1.005 AND C/REF(C,1)>1.015),10);
STICKLINE(试盘K,O,C,5,0),COLOR221199;
STICKLINE(试盘K,O,C,2,0),COLORAAFF99;
STICKLINE(试盘K,O,C,1,0),COLOR0000FF;
试盘周期:=BARSLAST(试盘K);
震仓K:=FILTER(COUNT(试盘K,10)>=1 AND H<HHV(H,试盘周期+1) AND C>=多空线 AND C<O,3);
震仓周期:=BARSLAST(震仓K);
起爆K:=FILTER(REF(COUNT(试盘K,7)>=1,3) AND C>=REF(H,震仓周期) AND C>O AND 多空线>REF(多空线,1),2);
STICKLINE(震仓K,O,C,1,0),COLOR2288FF;
STICKLINE(起爆K,H,L,0,0),COLORFF88FF;
STICKLINE(起爆K,O,C,4,0),COLORFF88FF;
DRAWTEXT(震仓K,H*1.024,'震'),COLOR999999;
STICKLINE((C/REF(C,1))>1.095 AND C>O,O,C,1,0),COLORFFFFFF;
STICKLINE((C/REF(C,1))>1.095 AND C>O,(C+O)/2,C,3,0),COLOR0000AA;
STICKLINE(ZT,L,H,0.1,0),COLOR0000FF;
STICKLINE(ZT,O,C,3.2,0),COLOR0000AA;
STICKLINE(ZT,O,C,2.4,0),COLOR0000BB;
STICKLINE(ZT,O,C,1.8,0),COLOR0000CC;
STICKLINE(ZT,O,C,1.2,0),COLOR0000DD;
STICKLINE(ZT,O,C,0.5,0),COLOR0000EE;
STICKLINE(DT,H,L,0.3,0),COLOR00EE00;
STICKLINE(DT,O,C,3,0),COLOR00EE00;
STICKLINE(ZB,H,L,0.1,0),COLORFF3399;
STICKLINE(ZB,O,C,3,0),COLORFF3399;
STICKLINE(ZT,(C*2+H)/3,C,2,0),COLORFFFFFF;
DRAWICON(FILTER(突破,5),L*0.98,42);
DRAWTEXT(ISLASTBAR AND 持续画线,建仓*0.97,VARCAT('建仓:',VAR2STR(建仓,2))),COLOR5599FF;
DRAWTEXT(ISLASTBAR AND 持续画线 AND C<加仓,C*0.93,'XP'),COLORLIBLUE;
DRAWTEXT(ISLASTBAR AND 持续画线 AND C>加仓,C*0.85,'加仓区间'),COLORFFAA99;
龙马:=DMA(AMOUNT/V/100,V/CAPITAL);
飞龙:龙马*1.1,COLORFFFF55,DOTLINE;
强势模式:=CLOSE>飞龙 AND REF(CLOSE,1)<=REF(飞龙,1)
AND REF(CLOSE,2)<=REF(飞龙,2);
{1. 影线：最高价到飞龙线}
STICKLINE(H>飞龙, H, MAX(飞龙,MIN(O,C)), 0,0),COLORYELLOW;
{2. K实体，实体跨飞龙线，实体高于飞龙的部分画黄色}
STICKLINE(MAX(O,C)>飞龙, MAX(O,C), MAX(MIN(O,C),飞龙), 2.9,0),COLORYELLOW;
散户:100*(HHV(H,55)-C)/(HHV(H,55)-LLV(L,55)),NODRAW;
控盘:100*WINNER(C*0.95),NODRAW;
P01:=90;A8:=P01+(100-P01)/2;B:=(100-P01)/2;
CCC:=COST(A8);DD:=COST(B);
筹码度:=(CCC-DD)/(CCC+DD)*100,NODRAW;
锁仓:=IF(筹码度<=10, EMA(WINNER(C)*100/2,2),0),COLOR4455FF,NODRAW;
关注:=(散户<20 AND 控盘>55) OR (控盘>30 AND 锁仓>47);
DRAWTEXT(关注,H*1.015,'^'),COLOR80FFFF;
盘:=(EMA(EMA(C,13),13)-REF(EMA(EMA(C,13),13),1))/REF(EMA(EMA(C,13),13),1)*1000;
主力操盘:=盘>REF(盘,1) AND 盘>0;
均线金叉:=CROSS(EMA(C,5),MA(C,10)) OR CROSS(EMA(C,5),EMA(C,12)) OR CROSS(MA(C,10),EMA(C,7)) OR (CROSS(EMA(C,5),EMA(C,7)) AND CROSS(EMA(C,5),EMA(C,12)));
价格强势:=C>O AND C>REF(C,1) AND C/REF(C,1)>=1.018;
机构启动:=主力操盘 AND 均线金叉 AND 价格强势;
机构启动K:=机构启动 AND MACD>0 AND C>MA(C,5);
STICKLINE(机构启动K,(C*2+O)/3,C,1.5,1),COLOR00FF00;
STICKLINE(机构启动K,(C*2+O)/3,H,0.2,0),COLOR50FFFF;
时限:=CURRBARSCOUNT<=7;
成本50:=COST(50);
前期高峰:=REF(HHV(COST(50),21),1);
左:=前期高峰;
突破左峰:=CROSS(C,左) AND V/REF(V,1)>1.05 AND V>REF(MA(V,5),1)*1.2;
短成本:IF(时限,CONST(成本50),DRAWNULL),COLORFF3399,LINETHICK2;
左峰:IF(时限,CONST(左),DRAWNULL),COLOR44FFFF,LINETHICK2;
H21:=HHV(H,21);
L21:=LLV(L,21);
回踩价:=(H21-L21)/3+L21,NODRAW;
回踩:CONST(回踩价),COLORCCCCFF,LINETHICK2;
买点触发:=ABS(L-回踩价)/回踩价<=0.02 AND C>EMA(C,30);
DRAWTEXT(FILTER(买点触发,4),L*0.98,'回踩'),COLOR00FFFF;
AB1:=IF((CLOSE>REF(CLOSE,1)),88,0);AB2:=IF(((CLOSE)/(REF(CLOSE,1))>1.05) AND ((HIGH)/(CLOSE)<1.01) AND (AB1>0),91,0);XG:=(FILTER((AB2>90),45)),COLORYELLOW;
DRAWTEXT(XG>0,H*0.92,'【异动单】'),COLORFFDDDD;
DRAWNUMBER(XG>0,(C*2+L+H)/4*0.98,ROUND((C*2+L+H)/4*100)/100),COLOR00FFFF;
建:=SMA(MAX(C-REF(C,1),0),4.1,1)/SMA(ABS(C-REF(C,1)),4.1,1)*100;
抄底:=CROSS(建,11);
DRAWTEXT(抄底,L*0.96,'抄底'),COLORFF00FF;
AMOW:=AMOUNT/10000.0;
亿级:=CONST(10000);
双倍量:=(V/REF(MA(V,5),1)>=2) OR (V/REF(V,1)>=3);
倍量过前五:=C>O AND 双倍量 AND C>EMA(C,13) AND V=HHV(V,6);
钱袋子:=CROSS(AMOW,亿级);
三合一:=(倍量过前五 AND 钱袋子);
DRAWICON(钱袋子,H*1.03,9);
DRAWTEXT(三合一,L*0.927,'周K共振'),COLOR00FFFF;
实体:=ABS(C-O); 上影:=H-MAX(O,C); 振幅:=(H-L)/REF(C,1); 涨幅:=(C/REF(C,1)-1)*100;
量比5:=V/MA(V,5);
试盘:=上影>=实体*1.2 AND 上影>=(H-L)*0.45 AND 振幅>=0.03 AND 量比5<3.5
AND C>MA(C,20)*0.9 AND (C/REF(C,10)-1)*100<25;
起涨:=C>O AND 涨幅>=2 AND 量比5>=1.2 AND C>MA(C,5);
震盘:=C<=O AND H<REF(H,1) AND V<REF(V,1)*0.9 AND L>REF(L,1)*0.93;
试盘距今:=BARSLAST(试盘); 起涨距今:=BARSLAST(起涨);
起涨开盘:=REF(O,起涨距今); 试盘开盘:=REF(O,试盘距今);
破位:=L<起涨开盘;
E1:=震盘 AND 量比5<0.65 AND L>=起涨开盘 AND 振幅<0.035;
E2:=震盘 AND L<=起涨开盘*1.015 AND C>=起涨开盘*0.995 AND C>=O;
E3:=震盘 AND 破位 AND C>起涨开盘 AND C>O;
E5:=震盘 AND 破位 AND L>=试盘开盘 AND C>=试盘开盘 AND 量比5<0.85 AND 振幅<0.06;
DRAWICON(E5,L*0.985,1); {黄金坑：红箭头}
DRAWICON(E2,L*0.985,33); {回踩起涨开盘：笑脸}
DRAWICON(E3,L*0.985,23); {破位回收：向上箭头}
DRAWICON(E1,L*0.985,25); {缩量企稳：小圆}
DRAWTEXT(E5,L*0.97,'坑'),COLORYELLOW;
STICKLINE(E5,O,C,3,0),COLORYELLOW;
{链条参考位画虚线，便于肉眼确认}
链条线:IF(起涨距今<=试盘距今 AND 起涨距今<20,起涨开盘,DRAWNULL),COLORRED,DOTLINE;
深位线:IF(起涨距今<=试盘距今 AND 起涨距今<20,试盘开盘,DRAWNULL),COLORGREEN,DOTLINE;

不要单一依靠主图来做买卖决策，它只属于辅助工具。实盘一定要结合成交量、K线形态、均线、板块热点共振使用，才能提高胜率。

再次提醒：本文指标仅技术学习交流，不构成任何投资建议。股市风险自担。

风险提示⚠️
本文所介绍公式源码仅为行情数据量化学习工具，无证券投资咨询资质，不构成任何股票买卖建议。A股短线交易波动极大，存在本金亏损风险，所有操作请结合自身风险承受能力自主决策，谨慎参与。文中策略、图中个股，以及参数仅为技术逻辑分享，过往市场表现不代表未来收益。